1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
set title "$v(\\mathbf x)=e^{-|\\mathbf x|}$"
set ylabel "energy relative error" offset +3
set xlabel "$\\rho$"
set xtics 1e-6, 100, 100
set xtics add ("$10^{-6}$" 0.000001, "$10^{-4}$" 0.0001, "$10^{-2}$" 0.01, "$1$" 1.0, "$10^2$" 100)
unset mxtics
set xrange [1e-7:1e2]
set ytics 1e-5, 10, 1e-1
set ytics add ("$10^{-5}$" 1e-5, "$10^{-4}$" 1e-4, "$10^{-3}$" 1e-3, "$10^{-2}$" 1e-2, "$10^{-1}$" 1e-1)
set yrange [1e-6:1e-1]
# default output canvas size: 12.5cm x 8.75cm
set term lua tikz size 8,6 standalone
set key bottom left box linetype rgbcolor"#999999" width 0.3 height 0.3 spacing 1.3
# set linestyle
set style line 1 linetype rgbcolor "#4169E1" linewidth 2 dashtype "."
set style line 2 linetype rgbcolor "#DC143C" linewidth 2
set style line 3 linetype rgbcolor "#32CD32" linewidth 2 dashtype "-"
set style line 4 linetype rgbcolor "#4B0082" linewidth 2
set style line 5 linetype rgbcolor "#DAA520" linewidth 2
set pointsize 1
max(x,y)=(x>y ? x : y)
set logscale xy
plot \
"simpleq1.dat" using 1:($3<1e-5 ? max(abs($2-$5)/$5,abs($2-$6)/$6) : 1/0) every ::1 with lp ls 1 title "simple" ,\
"mueq1.dat" using 1:($3<1e-5 ? max(abs($2-$5)/$5,abs($2-$6)/$6) : 1/0) every ::1 with lp ls 3 title "med" ,\
"bigeq1.dat" using 1:($3<1e-5 ? max(abs($2-$5)/$5,abs($2-$6)/$6) : 1/0) every ::1 with lp ls 5 title "big" ,\
"2020-10-15+energy.dat" using 1:(max(max(abs($6-$2)/$2,abs($6-$3)/$3),max(abs($7-$2)/$2,abs($7-$3)/$3))) every ::1 with lp ls 2 title "BDJ"
|
