set title "$v(\\mathbf x)=e^{-|\\mathbf x|}$"
set ylabel "energy relative error" offset +3
set xlabel "$\\rho$"

set xtics 1e-6, 100, 100
set xtics add ("$10^{-6}$" 0.000001, "$10^{-4}$" 0.0001, "$10^{-2}$" 0.01, "$1$" 1.0, "$10^2$" 100)
unset mxtics
set xrange [1e-6:1e2]

set ytics 1e-5, 10, 1e-1
set ytics add ("$10^{-5}$" 1e-5, "$10^{-4}$" 1e-4, "$10^{-3}$" 1e-3, "$10^{-2}$" 1e-2, "$10^{-1}$" 1e-1)
set yrange [1e-5:1e-1]

# default output canvas size: 12.5cm x 8.75cm
set term lua tikz size 8,6 standalone

unset key


# set linestyle
set style line 1 linetype rgbcolor "#4169E1" linewidth 2
set style line 2 linetype rgbcolor "#DC143C" linewidth 2
set style line 3 linetype rgbcolor "#32CD32" linewidth 2
set style line 4 linetype rgbcolor "#4B0082" linewidth 2
set style line 5 linetype rgbcolor "#DAA520" linewidth 2

set pointsize 1

max(x,y)=(x>y ? x : y)

set logscale xy

plot \
 "simpleq1.dat" using 1:($3<1e-5 ? max(abs($2-$5)/$5,abs($2-$6)/$6) : 1/0) every ::1 with lp ls 1 ,\
 "bigeq1.dat" using 1:($3<1e-5 ? max(abs($2-$5)/$5,abs($2-$6)/$6) : 1/0) every ::1 with lp ls 4 ,\
 "2020-10-15+energy.dat" using 1:(max(max(abs($6-$2)/$2,abs($6-$3)/$3),max(abs($7-$2)/$2,abs($7-$3)/$3))) every ::1 with lp ls 2